gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/ChgInfo.asp

    <!--#include file="Head.asp"-->
<!--#include file="Function.asp"-->
<!--#include file="Inc/Md5.asp"-->
<!--#include file="Api/Api_Class.asp"-->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

With Netout
	.Load("Comm")
	IF .UserName = "" Then
		.ShowErr(6)
		Response.End()
	End IF
	Dim Action,rs,Password,Email,Question,Answer,Phone,Mobile,UserInfo,UserEmail
	Action = .CheckStr(request.QueryString("Action"),"")
	IF Action = "Modify" Then
		Password = request.Form("Password")
		PrePassword = request.Form("PrePassword")
		IF Password<>"" Then
			Password = .ReplaceBadChar(trim(Request.Form("Password")))
			IF Len(Password)<6 Or Len(Password)>16 Then
				.ShowErr(3)
				Response.End()
			End IF
			IF PrePassword<>Password Then
				.ShowErr(4)
				Response.End()
			End IF
		End IF
		
		TrueName = Server.HTMLEncode(Trim(Request.Form("TrueName")))
		ManuName = Server.HTMLEncode(Trim(Request.Form("ManuName")))
		Email=trim(request.form("Email"))
		UserPic=Trim(Request.Form("Image"))
		Question=request.form("Question")
		Answer=request.form("Answer")
		Phone=request.form("Phone")
		Mobile=request.form("Mobile")
		Desc = .HtmlEncode(Trim(Request.Form("Desc")),True)
		
		Set Rs=server.createobject("adodb.recordset")
		Rs.open "select * from NT_User where UserName='"&.UserName&"'",Conn,1,3
		IF Not(Rs.eof or Rs.eof) Then
			'-----------------------------------------------------------------
			'系统整合
			'-----------------------------------------------------------------
			Dim objApi,SysKey
			If Api_Enable Then
				Set objApi = New Lyout_Api
				objApi.NodeValue "action","update",0,False
				objApi.NodeValue "username",.UserName,1,False
				objApi.NodeValue "truename",TrueName,1,False
				Md5OLD = 1
				SysKey = Md5(objApi.XmlNode("username")&Api_SysKey,Api_Md5_Len)
				Md5OLD = 0
				objApi.NodeValue "syskey",SysKey,0,False
				objApi.NodeValue "password",Password,1,False
				objApi.NodeValue "email",Email,1,False
				objApi.NodeValue "question",Question,1,False
				objApi.NodeValue "answer",Answer,1,False
				objApi.NodeValue "mobile",Mobile,1,False
				objApi.NodeValue "phone",Phone,1,False
				objApi.SendHttpData
				If objApi.Status = "1" Then
					.ShowError(objApi.Message)
					Response.End()
				End If
				Set objApi = Nothing
			End If

			Rs("TrueName") = TrueName
			Rs("ManuName") = ManuName
			IF Password<>"" Then
				Rs("Password")=md5(Password,Api_Md5_Len)
			End IF
			Rs("UserEmail")=Email
			IF UserPic<>"" Then
				UserImage = Rs("UserPic")&""
				IF UserImage<>"" Then
					UserImage = split(UserImage,",")
					Set fo=server.CreateObject("Scripting.FileSystemObject")
					If fo.FileExists(server.MapPath(UserImage(0))) Then	fo.DeleteFile server.MapPath(UserImage(0))
					Set fo=nothing
				End IF
				Rs("UserPic")=UserPic
			End IF
			Rs("Phone")=Phone
			Rs("Mobile")=Mobile
			IF Question<>"" Then Rs("Question")=Question
			IF Answer<>"" Then Rs("Answer")=MD5(Answer,Api_Md5_Len)
			Rs("userDesc")=Desc
			Rs.update
			Rs.close
			
			Set Rs=nothing
			If Config.Settings(27) = "1" And Config.WaterMark(0) = "1" And IsHttpUrl Then
				DataValue = Config.SystemUrl&"#%##"&.UserName&"$##@"&TrueName&"$##@"&ManuName&"$##@"&UserEmail&"$##@"&Phone&"$##@"&Mobile
				.SendData "EditInfo.asp?Action=User",DataValue
			End If
			Response.write("<script>alert('"&.theCode(5)&"');this.location.href='Admin_LogOut.asp';</script>")
		End IF		
	Else
		Set Rs = Server.CreateObject("Adodb.recordset")
		Rs.Open "select * from NT_User where UserName='"&.UserName&"'",Conn,1,1
		MyHtml = replace(replace(Template.Html(9),"{?UserName}",.UserName),"{?UserEmail}",Rs("UserEmail")&"")
		MyHtml = Replace(Replace(MyHtml,"{?TrueName}",Rs("TrueName")&""),"{?ManuName}",Rs("ManuName")&"")
		MyHtml = replace(replace(replace(MyHtml,"{?Phone}",Rs("Phone")&""),"{?Mobile}",Rs("Mobile")&""),"{?Desc}",Rs("userDesc")&"")
		MyHtml = replace(Replace(Replace(Split(Template.Html(0),"||")(0),"{?left_beg}",""),"{?left_end}",""),"{?RightInfo}",MyHtml)
		MyHtml = replace(.TempHtml,"{?CurrentScript}",Replace(MyHtml,"{?LeftInfo}",Replace(Template.Html(1),"{?QuickLaunch}",QuickLaunch())))
		Rs.Close
		Set Rs = Nothing
		Response.Write(MyHtml)
	End IF
End With
Set Template = Nothing
Set Netout = Nothing
%>